Styjun

I have found a macro written for Excel that has the exact function that I need but I don't know how to convert it for use in Word - I'm fairly new to scripting and the only language/syntax that I'm familiar with is the Aspect scripting language that I've been learning from working with Procomm Plus. I found the Excel macro here:

Find specific text and delete three rows above it

Sub Delete()
Dim find As String: find = "TOT"
Dim rng As Range

Set rng = Sheets("Sheet1").Cells.find(What:=find, After:=Sheets("Sheet1").Cells(1, 1), LookIn:=xlValues, Lookat:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=True)

If Not rng Is Nothing Then
 rng.EntireRow.Delete
 rng.Offset(-1).EntireRow.Delete
 rng.Offset(-2).EntireRow.Delete
 rng.Offset(-3).EntireRow.Delete
End If

End Sub

I need the macro to look for the the text "% Invalid input detected at ‘^’ marker" and then delete it, as well as the two lines above that phrase:

Router#show environment all ;(let's call this "line -2")
 ^ ;(and this would be "line -1")
% Invalid input detected at ‘^’ marker ;(and "line 0")

This is the console output from a Cisco router (copy/pasted to Word) and the phrase "% Invalid input detected at ‘^’ marker" is always the same but the two lines above it can vary, depending on what Cisco command I have used that has not been recognised.

I think the solution is probably quite simple but I'm stuck!

I found another macro for Word that performs a similar function and - it looks for a key phrase and deletes the line containing that phrase but again, I'm not sure how to extend it to include the preceding two lines of text:

Sub InvalidInput()
Dim oRng As Word.Range
Set oRng = ActiveDocument.Range
With oRng.Find
 .Text = "Invalid input detected"
 While .Execute
 oRng.Paragraphs(1).Range.Delete
 Wend
End With
End Sub

Would anyone be able to suggest some edits that could solve my problem? Thank you very much in advance.

Assuming your 'lines' are separate paragraphs, try:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
 With .Find
 .ClearFormatting
 .Replacement.ClearFormatting
 .Text = "[!^13]@^13[!^13]@^13% Invalid input detected at ‘^94’ marker^13"
 .Replacement.Text = ""
 .Forward = True
 .Wrap = wdFindStop
 .Format = False
 .MatchWildcards = True
 .Execute Replace:=wdReplaceAll
 End With
End With
Application.ScreenUpdating = True
End Sub

Otherwise, you'll have to provide a more meaningful description of what delineates your 'lines'.

This is a longshot but have a go at this macro in Word ...

Public Sub RemoveUnwantedParagraphs()
 Dim objParagraph As Paragraph, arrToRemove() As Long, lngIndex As Long
 Dim i As Long, x As Long, strSearchFor As String

 strSearchFor = "% Invalid input detected at '^' marker"

 lngIndex = -1

 For i = 1 To ThisDocument.Paragraphs.Count
 Set objParagraph = ThisDocument.Paragraphs(i)

 If Left(objParagraph.Range.Text, Len(strSearchFor)) = strSearchFor Then
 For x = 2 To 0 Step -1
 lngIndex = lngIndex + 1
 ReDim Preserve arrToRemove(lngIndex)
 arrToRemove(lngIndex) = i - x
 Next
 End If
 Next

 On Error GoTo ExitGracefully

 For i = UBound(arrToRemove) To 0 Step -1
 ThisDocument.Paragraphs(arrToRemove(i)).Range.Delete
 Next

ExitGracefully:

End Sub

... do yourself one favour though before you run it, BACKUP YOUR DOCUMENT!!!.

I make no guarantees that it won't inadvertently stuff up the entire thing. I've done limited development in Word but that code above did work for me.

The only thing to note is that if the text you're searching for is contained in the 1st or 2nd row, it may break. I figure that's not expected though so didn't cater for it.