Styjun

I'm a newbie on this. So after pressing the new record button and create a new record on the Company tab, the job# on Company tab increases by one but the problem is the job# of Private tab would increase as well. The job# Private tab should stay zero unless I press the add new record button. I used the same single step script for both of them (new record/request).

If both fields are from same table and if you have used Auto Enter Serial number, it will increment both.
Uncheck the auto enter serial and increase the numbers using script by calculating the maximum + 1.

You could create a separate Sequence table for job numbers, public and private being stored in separate records.

Sequence Fields:

• type (TEXT)


• lastAssignedNumber (NUMBER)

Then create a script called Next Sequence ( $type )

Set Variable [ $type = Get(ScriptParameter) ]
Go to layout [ Sequence ]
Set Error Capture [ On ]
Perform Find [ type ==$type ]
If [GetLastError]
 Show Custom Dialog [ "Invalid sequence " & Quote( $sequence ) ]
 Halt Script
End If

Loop
 Open Record/Request
 Exit Loop If [ not Get(LastError) ]
 # Error opening record, someone else has a lock on this sequence record
 # Wait a bit and try again
 Pause/Resume Script [ 0.1 ]
End Loop
Set Field [ Sequence::lastAssignedNumber ; Sequence::lastAssignedNumber + 1 ]
Set Variable [ $result = Sequence::lastAssignedNumber ]
Commit Records/Requests
Go to Layout [ original ]
Exit Script [ $result ]

This takes a parameter "type" and exits with a newly assigned sequence number for that type. You'll need to create two records in the Sequence table, giving them type values of "PublicJob" and "PrivateJob", e.g.

Then write two scripts for creating jobs

Create Public Job

New Record/Request
Perform Script [ "Next Sequence ( $type )" ; Parameter: "PublicJob" ]
Set Field [ Job#; Get(ScriptResult) ]

Create Private Job

New Record/Request
Perform Script [ "Next Sequence ( $type )" ; Parameter: "PrivateJob" ]
Set Field [ Job#; Get(ScriptResult) ]