Styjun

I've been having this issue in a larger program, so I made a new ada program to test it and I get the same thing.

I have a text file (Unix line endings) as so:

000_1000_0010_1001
100_0000_0010_1001
100_1000_0000_1001
100_1000_0010_0001
100_1000_0010_1001
000_0000_0011_0011
100_1000_0100
000_0000_0110
111_1111_1111
011_1111_1111
000_0000_0110

What I want to do with it is simple, put each line in a string and then just print it right back out.

this is my code:

with Ada.Text_IO; use Ada.Text_IO;
procedure Read is
 input: String(1..18);
 len: Natural;
begin
 while not End_Of_File loop
 Get_Line(input, len);
 Put_Line(input(1..len));
 end loop;

end Read;

Easy right? it takes in each line with get_line, saves it to "input" variable, and then prints out whatever amount of it was read in (using the length returned from get_line().

Unfortunately, I get a bunch of blank lines when I run this code:

gnatmake read read.adb
read < input.txt

000_1000_0010_1001

100_0000_0010_1001

100_1000_0000_1001

100_1000_0010_0001

100_1000_0010_1001

000_0000_0011_0011

100_1000_0100
000_0000_0110
111_1111_1111
011_1111_1111
000_0000_0110

I have gone through and made sure I dont have any weird line ending characters in my input file or anything like that (I just typed them out in vim).

This is messing up my program, because i have to account for these erroneous empty lines.

Any idea what I'm doing wrong here?

Your input variable can hold 18 characters, and Get_Line knows this, so when your input line is more than 18 characters long, it will read only 18 characters. It will then proceed to read the same line until either another 18 characters have been read, or the end of line has been reached. In your case, the input line is exactly 18 characters long (not counting the end of line), which just looks weird when the end of line is reached with no characters read into the input variable (len returns 0)...

You can either increase the length of your input buffer to be bigger than any input you can think of, or let the runtime figure out how long the line is by using the function Get_Line return String;:

with Ada.Text_IO; use Ada.Text_IO;
procedure Read is
begin
 while not End_Of_File loop
 declare
 input : String := Get_Line;
 begin
 Put_Line(input);
 end;
 end loop;
end Read;

In addition to egilhh answer,

First understand the background: there may be lines of text longer than the string provided, so line read is incomplete and it is required to call Get_Line more than one time to read whole line.

To detect this case an application simply check if string is filled full, and read the rest. For this to work, Get_Line treats the case of matched lengths as incomplete line, leaving 'rest' of line (0 chars) unread.

So, another solution exist:

 while not End_Of_File loop
 Get_Line(input, len);
 if len < input'Last then
 Put_Line(input(1..len)); -- whole (or the rest of previous) line read,
 else
 Put(input); -- (non-final) part of long line read, do not go to next
 end if;
 end loop;

or

 while not End_Of_File loop
 Get_Line(input, len);
 Put(input(1..len)); -- do not emit eol yet...
 if len < input'Last then
 New_Line; -- now we know: line is finished
 end if;
 end loop;