Styjun

This is my code:

Sub WO_Porownanie_Planu_do_Realizacji()
 ActiveSheet.Range("H3").Select
 Dim p2 As Double
 Dim LR As Double
 Dim Wynik As Integer
 LR = Range("A" & Rows.count).End(xlUp).Row
 p2 = LR
 MsgBox (p2)
 'p2 = Range(Selection, ActiveCell.End(xlDown)).count + 2

 Dim myfilein As String
 myfilein = Application.GetOpenFilename

 Dim wrks1 As Worksheet
 Set wrks1 = ActiveSheet
 Dim wrkbk As Workbook
 Dim wrks As Worksheet

 Set wrkbk = Workbooks.Open(myfilein)
 Set wrks = wrkbk.Worksheets(1) 

 For wiersze = 3 To p2
 For kolumny = 9 To 20
 a1 = wrks1.Cells(wiersze, kolumny)
 a2 = wrks.Cells(wiersze, kolumny)
 Set Rng = wrks1.Cells(wiersze, kolumny)
 Rng.ClearComments
 Rng.AddComment

 Wynik = a1 - a2
 Rng.Comment.Text Text:="Zaoszczedzono: " & Wynik
 Next
 Next
End Sub

This code compare 2 excel files and writes comments with difference between numbers on 2 sheets. I don't have any problems while testing on small sheets.

Example:

But while im trying on Big files I've got error:

Run-time error'13': Type mismatch.

And the whole makro stops in cell I67 and the comment only in this cell is empty.

I had to censor some cells.

Have you got any idea how to fix it?

I try to modify the code . Try the new version and if you need help let me know:

Option Explicit

Sub WO_Porownanie_Planu_do_Realizacji()

' ActiveSheet.Range("H3").Select
' p2 = LR
' p2 = Range(Selection, ActiveCell.End(xlDown)).count + 2
' Dim p2 As Double

 Dim LR As Long, wiersze As Long, kolumny As Long
 Dim Wynik As Double, a1 As Double, a2 As Double
 Dim wrks As Worksheet
 Dim wrkbk As Workbook
 Dim myfilein As String
 Dim rng As Range

 With ThisWorkbook.Worksheets("Sheet1")

 LR = Range("A" & Rows.Count).End(xlUp).Row

 MsgBox (LR)

 myfilein = Application.GetOpenFilename

 Set wrkbk = Workbooks.Open(myfilein)
 Set wrks = wrkbk.Worksheets(1)

 For wiersze = 3 To LR

 For kolumny = 9 To 20

 a1 = .Cells(wiersze, kolumny)
 a2 = wrks.Cells(wiersze, kolumny)
 Set rng = .Cells(wiersze, kolumny)
 rng.ClearComments
 rng.AddComment

 Wynik = a1 - a2
 rng.Comment.Text Text:="Zaoszczedzono: " & Wynik
 Next

 Next

 End With

End Sub

A possible cause of your type mismatch on the line with a1 - a2:

Your IFERROR statement (JEZELI.BLAD) is putting a "" into the cell (if the formula in I67 is the same as the one you show for J67)

When you execute the subtraction, you cannot have a "" as one of the factors, hence the error.

One work-around would be to test the values of a1 and a2 before doing the subtraction.

eg:

If VarType(a1) = vbString Then a1 = 0
If VarType(a2) = vbString Then a2 = 0

or maybe something like:

Dim a1 As Double, a2 As Double 
a1 = Val(wrks1.Cells(wiersze, kolumny))
a2 = Val(wrks.Cells(wiersze, kolumny))

which will convert a non-numeric string to zero (0)