Styjun

I am doing transform xml file using xslt and I want to display the error message of xslt parser in an element

Note: Error message should be original of parser message

I am not sure there is a way to capture XML parsing errors of the primary input document to an apply-templates based XSLT 3 transformation but in general XSLT 3 with xsl:try/xsl:catch allows you to capture and handle run-time errors, so assuming you can organize the rest of your code (for instance by using a named template as the starting point) to load/parse any XML documents with the doc or document function then you can use try/catch to handle parsing errors. An example is https://xsltfiddle.liberty-development.net/ej9EGcg/2

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:err="http://www.w3.org/2005/xqt-errors"
 exclude-result-prefixes="#all"
 version="3.0">

<xsl:template match="/">
 <root>

 <xsl:try>
 <xsl:variable name="doc1" select="doc('https://raw.githubusercontent.com/martin-honnen/martin-honnen.github.io/master/xslt/2019/test2019032601.xml')"/>
 <xsl:value-of select="count($doc1//item)"/>
 <xsl:catch>Error code: <xsl:value-of select="$err:code"/>
 Reason: <xsl:value-of select="$err:description"/>
 </xsl:catch>
 </xsl:try>

 </root>
</xsl:template>

</xsl:stylesheet>

which, depending on your needs, can also be reduced to directly use the relevant XPath expression with the select attribute of the xsl:try element e.g. https://xsltfiddle.liberty-development.net/ej9EGcg/3

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:err="http://www.w3.org/2005/xqt-errors"
 exclude-result-prefixes="#all"
 version="3.0">

<xsl:template match="/">
 <root>

 <xsl:try select="count(doc('https://raw.githubusercontent.com/martin-honnen/martin-honnen.github.io/master/xslt/2019/test2019032601.xml'))">
 <xsl:catch>Error code: <xsl:value-of select="$err:code"/>
 Reason: <xsl:value-of select="$err:description"/>
 </xsl:catch>
 </xsl:try>

 </root>
</xsl:template>

</xsl:stylesheet>